dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.57)
AC_INIT(libqedr, 8.33.1.0, linux-rdma@vger.kernel.org)
AC_CONFIG_SRCDIR([src/qelr_main.h])
AC_CONFIG_AUX_DIR(config)
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(libqedr, 8.33.1.0)
AM_PROG_LIBTOOL

AC_ARG_ENABLE(libcheck, [ --disable-libcheck    do not test for the presence of ib libraries],
[	if test x$enableval = xno ; then
		disable_libcheck=yes
	fi
])

dnl Checks for programs
AC_PROG_CC
AC_CHECK_SIZEOF(long)

dnl Checks for libraries
if test "$disable_libcheck" != "yes"
then
AC_CHECK_LIB(ibverbs, ibv_get_device_list, [],
    AC_MSG_ERROR([ibv_get_device_list() not found.  libqedr requires libibverbs-devel.]))
fi

dnl Checks for header files.
AC_CHECK_HEADERS(sysfs/libsysfs.h)

if test "$disable_libcheck" != "yes"
then
AC_CHECK_HEADER(infiniband/driver.h, [],
    AC_MSG_ERROR([<infiniband/driver.h> not found.  Is libibverbs installed?]))
AC_HEADER_STDC
fi

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST

dnl Checks for library functions
AC_CHECK_FUNCS(ibv_read_sysfs_file ibv_register_driver)

dnl Check for libibverbs device library extension
dummy=if$$
cat <<IBV_VERSION > $dummy.c
#include <infiniband/driver.h>
IBV_DEVICE_LIBRARY_EXTENSION
IBV_VERSION
IBV_DEVICE_LIBRARY_EXTENSION=`$CC $CPPFLAGS -E $dummy.c 2> /dev/null | tail -1`
rm -f $dummy.c
if test $IBV_DEVICE_LIBRARY_EXTENSION = IBV_DEVICE_LIBRARY_EXTENSION; then
    AC_MSG_ERROR([IBV_DEVICE_LIBRARY_EXTENSION not defined.  Is libibverbs new enough?])
fi
AC_SUBST(IBV_DEVICE_LIBRARY_EXTENSION)

AC_CACHE_CHECK(whether ld accepts --version-script, ac_cv_version_script,
    if test -n "`$LD --help < /dev/null 2>/dev/null | grep version-script`"; then
        ac_cv_version_script=yes
    else
        ac_cv_version_script=no
    fi)

AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$ac_cv_version_script" = "yes")
AM_CONDITIONAL(FMODEL, test "$FMODEL" = "1")

AC_CONFIG_FILES([Makefile libqedr.spec])
AC_OUTPUT