#
# Copyright (c) 2001-2013 NetApp, Inc., All Rights Reserved
#   Any use, modification, or distribution is prohibited
#   without prior written consent from NetApp, Inc.
#

## @summary LunPortset ComponentState Module
## @author dl-nacl-dev@netapp.com
## @status shared
## @pod here

=head1 NAME

NACL::CS::LunPortset

=head1 DESCRIPTION

C<NACL::CS::LunPortset> is a derived class of
L<NACL::CS::ComponentState::ONTAP|lib-NACL-CS-ComponentState-ONTAP-pm>. It represents the
state of an ONTAP LunPortset.  A related class is
L<NACL::C::LunPortset|lib-NACL-C-LunPortset-pm>, which represents access
to an ONTAP LunPortset.

=head1 ATTRIBUTES

The individual pieces of data that are part of the  state of the LunPortset
element are the attributes of the LunPortset ComponentState.

=over

=item C<< "tpg" >>

=item C<< "port_name" >>

Filled in for CMode CLI, CMode ZAPI.

CMode ZAPI: Accessible through the field "portset-port-name" in the output of ZAPI "portset-get-iter"
(Array)

Maps to:

CM ZAPI:

For "requested_fields", "filter" and Output mapping:

<portset-info>
    <portset-port-info>
        <portset-port-name>@values</portset-port-name>
    </portset-port-info>
</portset-info>

=item C<< "vserver" >>

Filled in for CMode CLI/ZAPI.

Maps to:

CM ZAPI:

For "requested_fields", "filter" and Output mapping:

<portset-info>
    <vserver>$value</vserver>
</portset-info>

=item C<< "fcp" >>

=item C<< "igroups" >>

Filled in for CMode CLI, CMode ZAPI.

CMode ZAPI: Accessible through the field "initiator-group-info" in the output of ZAPI "portset-get-iter"
(Array)

Maps to:

CM ZAPI:

For "requested_fields", "filter" and Output mapping:

<portset-info>
    <initiator-group-info>
        <initiator-group-name>@values</initiator-group-name>
    </initiator-group-info>
</portset-info>

=item C<< "port_count" >>

Filled in for CMode CLI, CMode ZAPI.

CMode ZAPI: Accessible through the field "portset-port-total" in the output of ZAPI "portset-get-iter"

Maps to:

CM ZAPI:

For "requested_fields", "filter" and Output mapping:

<portset-info>
    <portset-port-total>$value</portset-port-total>
</portset-info>

=item C<< "uuid" >>

Filled in for CMode CLI, CMode ZAPI.

=item C<< "portset" >>

Filled in for CMode CLI, CMode ZAPI , 7Mode CLI.

CMode ZAPI: Accessible through the field "portset-name" in the output of ZAPI "portset-get-iter"

Maps to:

CM ZAPI:

For "requested_fields", "filter" and Output mapping:

<portset-info>
    <portset-name>$value</portset-name>
</portset-info>

=item C<< "fc_lif" >>

=item C<< "protocol_type" >>

Filled in for CMode CLI, CMode ZAPI.

CMode ZAPI: Accessible through the field "portset-type" in the output of ZAPI "portset-get-iter"

=item C<< "iscsi" >>

=item C<< protocol >>

Filled in for CMode CLI/ZAPI.

Maps to:

CM ZAPI:

For "requested_fields", "filter" and Output mapping:

<portset-info>
    <portset-type>$value</portset-type>
</portset-info>

=item C<< vserver_uuid >>

Vserver UUID

Filled in for CMode CLI.


=back

=cut

package NACL::CS::LunPortset;

use strict;
use warnings;
use Params::Validate qw(validate);
use NACL::ComponentUtils qw(_dump_one Dumper);
use NATE::Log qw(log_global);
my $Log = log_global();
my $may_enter = $Log->may_enter();
my $may_exit  = $Log->may_exit();

use NACL::Exceptions::NoElementsFound qw(:try);
use NACL::CS::ComponentState::ZapiSkip qw(make_zapi_skip);
use NACL::CS::ComponentState::ZapiArray qw(make_zapi_array);

use base 'NACL::CS::ComponentState::ONTAP';

use Class::MethodMaker [
    scalar => 'tpg',
    array  => 'port_name',
    scalar => 'vserver',
    scalar => 'fcp',
    array  => 'igroups',
    scalar => 'port_count',
    scalar => 'uuid',
    scalar => 'portset',
    scalar => 'fc_lif',
    scalar => 'protocol_type',
    scalar => 'iscsi',
    scalar => 'protocol',
    scalar => 'vserver_uuid',
];

=head1 METHODS

=head2 fetch

    my $LunPortset_state   = NACL::CS::LunPortset->fetch(command_interface => $ci, ...);
	my @LunPortset_states = NACL::CS::LunPortset->fetch(command_interface => $ci, ...);

(Class method)
Discovers which elements are present and returns their state in ComponentState
objects. Called in scalar context it returns only one state object, in list
context it returns all state objects.
See L<NACL::CS::ComponentState|lib-NACL-CS-ComponentState-pm/fetch> for a
more detailed description along with a complete explanation of the options
it accepts.

Uses a CMode CLI or CMode ZAPI APISet or 7Mode CLI.

=over

=item Exceptions

=over

=item C<NACL::Exceptions::NoElementsFound>

When there are no elements matching the query specified or elements of that type
doesn't exist, then this exception will be thrown.

=back

=back

=cut

sub fetch {
    $Log->enter() if $may_enter;
    my $pkg        = shift;
    my @state_objs = $pkg->SUPER::fetch(
        @_,
        show_cmd =>'lun portset show',
        choices  => [
            {   method    => '_fetch_7mode_cli',
                interface => 'CLI',
                set       => '7Mode'
            },
            {   method    => '_fetch_cmode_cli',
                interface => 'CLI',
                set       => 'CMode'
            },
            {   method    => '_fetch_cmode_zapi',
                interface => 'ZAPI',
                set       => 'CMode',
            },
        ],
        exception_text => 'No matching lun portset(s) found'
    );

    $Log->exit() if $may_exit;
    return wantarray ? @state_objs : $state_objs[0];
} ## end sub fetch

sub _fetch_cmode_cli {
    $Log->enter() if $may_enter;
    my ($pkg, %opts) = @_;
    my @state_objs
        = $pkg->SUPER::_fetch_cmode_cli(%opts, api => 'lun_portset_show');
    $Log->exit() if $may_exit;
    return @state_objs;
} ## end sub _fetch_cmode_cli

sub _fetch_cmode_zapi {
    $Log->enter() if $may_enter;
    my ($pkg, %opts) = @_;
    my @state_objs = $pkg->SUPER::_fetch_cmode_zapi(
        %opts,
        api  => 'portset_get_iter',
        copy => [qw(vserver)],
        map  => {
            "portset"       => 'portset-name',
            "protocol-type" => 'portset-type',
            "port-count"    => 'portset-port-total',
            "igroups"       => [
                make_zapi_array('initiator-group-info'),
                make_zapi_skip('initiator-group-name')
            ],
            "port-name" => [
                make_zapi_array('portset-port-info'),
                make_zapi_skip('portset-port-name')
            ],
            "protocol" => 'portset-type'
        },
    );
    $Log->exit() if $may_exit;
    return @state_objs;
} ## end sub _fetch_cmode_zapi

sub _fetch_7mode_cli {
    $Log->enter() if $may_enter;
    my $pkg = shift;
    my %opts = validate @_, $pkg->_fetch_backend_validate_spec();
    my %api_opts;
    my @state_objs;
    my $apiset            = delete $opts{apiset};
    my $command_interface = delete $opts{command_interface};

    my %cmd_opts;
    my %copy_filter           = %{$opts{filter}};
    my @copy_requested_fields = @{$opts{requested_fields}};
    my $deleted_filter        = $pkg->_remove_relational_regex_filters(
        filter           => \%copy_filter,
        requested_fields => \@copy_requested_fields
    );
    my $filter           = \%copy_filter;
    my $requested_fields = \@copy_requested_fields;
    if ($filter->{portset}) {
        $cmd_opts{'portset-name'} = $filter->{'portset'};
    }
    my $response = $apiset->portset_show(%cmd_opts);
    my $output   = $response->get_parsed_output();

    foreach my $list_output (@$output) {

        my @all_ports;
        my $port_details = $list_output->{'port-details'};
        foreach my $elem (@$port_details) {
            my $node   = $elem->{'node'};
            my @this_p = @{$elem->{'ports'}};
            my @ports  = map { $node . ':' . $_ } @this_p;
            push(@all_ports, @ports);
        }
        $list_output->{ports} = \@all_ports;

        my $target = $pkg->_hash_copy(
            source => $list_output,
            copy   => [qw(igroups)],
            map    => {
                'ports'        => 'port_name',
                'portset-name' => 'portset',
            },
        );

        my $obj = $pkg->new(command_interface => $command_interface);
        $obj->_set_fields(row => $target);
        push @state_objs, $obj;
    } ## end foreach my $list_output (@$output)
    $Log->exit() if $may_exit;
    return @state_objs;
} ## end sub _fetch_7mode_cli

1;