# $Id$

#
# Copyright (c) 2001-2011 NetApp, Inc., All Rights Reserved
# Any use, modification, or distribution is prohibited
#  without prior written consent from NetApp, Inc.
#

## @summary NFS ComponentState Module
## @author vikas.p@netapp.com
## @status shared
## @pod here

=head1 NAME

NACL::CS::SysManager::NFS

=head1 DESCRIPTION

C<NACL::CS::SysManager::NFS> is a derived class of
L<NACL::CS::ComponentState::SysManager|lib-NACL-CS-ComponentState-SysManager-pm>.  It represents the  
state of an ONTAP NFS.  A related class is
L<NACL::C::SysManager::NFS|lib-NACL-C-SysManager-NFS-pm>, which represents access
to an ONTAP NFS.

=head1 ATTRIBUTES

The individual pieces of data that are part of the state of the NFS 
element are the attributes of the NFS ComponentState.

=over

=item C<< server_status >>

=item C<< version_3_support >>

=item C<< version_4_support >>

=item C<< version_2_support >>

Filled in for CMode.

=item C<< version_4_1_support >>

Filled in for CMode.

=back

=cut

package NACL::CS::SysManager::NFS;

use strict;
use warnings;
use NATE::Log qw(log_global);
my $Log = log_global();
my $may_enter = $Log->may_enter();
my $may_exit  = $Log->may_exit();
use Data::Dumper;
use Params::Validate qw(validate);

use base 'NACL::CS::ComponentState::SysManager';

use NACL::C::SysManager::NFS;
use NACL::Exceptions::NoElementsFound qw(:try);

# Import Exception class
use NACL::APISet::Exceptions::ResponseException qw(:try);
use NACL::APISet::Exceptions::CommandFailedException;

use Class::MethodMaker [
    scalar => 'vserver',
    scalar => 'server_status',
    scalar => 'version_3_support',
    scalar => 'version_4_support',

    scalar => 'version_2_support',
    scalar => 'version_4_1_support',
];

=head1 METHODS 

=head2 fetch

    my $nfs_state  = 
		NACL::CS::SysManager::NFS->fetch(command_interface => $ci,...);
    my @nfs_states = 
		NACL::CS::SysManager::NFS->fetch(command_interface => $ci,...);

see L<NACL::CS::ComponentState|lib-NACL-CS-ComponentState-pm>.

Uses a CMode GUI or a 7Mode GUI APISet.

=cut

sub fetch {
    $Log->enter() if $may_enter;
    my ( $pkg, @args ) = @_;

    my @state_objs = $pkg->SUPER::fetch(
        @args,
        choices => [
            {   method => "_fetch_cmode_gui",
                set    => "SysManager_CMode",
            },
            {   method => '_fetch_7mode_gui',
                set    => 'SysManager_7Mode',
            },
        ],
        exception_text => 'NFS not licensed/configured',
    );

    $Log->exit() if $may_exit;
    return wantarray ? @state_objs : $state_objs[0];
} ## end sub fetch

sub _fetch_cmode_gui {
    $Log->enter() if $may_enter;
    my ( $pkg, @args ) = @_;
    my %opts = validate @args, $pkg->_fetch_backend_validate_spec();

    my $apiset            = $opts{apiset};
    my $requested_fields  = $opts{requested_fields};
    my $filter            = $opts{filter};
    my $command_interface = $opts{command_interface};

    my $nfs_args = $pkg->_hash_copy(
        source => $filter,
        map    => { "vserver" => "-vservername", }
    );

    $pkg->_check_for_required_filter_fields(
        filter          => $filter,
        required_fields => [qw(vserver)],
    );

    my ( $response, $caught_exception, $parsed_output );
    try {

        # caling the gui api to get nfs status
        $response      = $apiset->get_nfs_info(%$nfs_args);
        $parsed_output = $response->get_parsed_output();
    } ## end try
    catch NACL::APISet::Exceptions::CommandFailedException with {

        # A caught exception indicates that the nfs is either not licensed
        # or not configured. We catch the exception and return immediately.
        # The 'fetch' frontend decides whether to throw a NoElementsFound
        # exception based on the value of 'allow_empty'
        $Log->debug(
            'CommandFailedException caught. NFS is not licensed/configured');
        $caught_exception = 1;
    };
    if ($caught_exception) {
        $Log->exit() if $may_exit;
        return;
    }

    my %state_base_field_settings;

    $state_base_field_settings{'vserver'} = $nfs_args->{'-vservername'};

    my %final_attributes = ( %state_base_field_settings, %$parsed_output );

    my $obj = $pkg->new( command_interface => $command_interface );
    $obj->_set_fields( row => \%final_attributes );
    $Log->exit() if $may_exit;

    return $obj;
} ## end sub _fetch_cmode_gui

sub _fetch_7mode_gui {
    $Log->enter() if $may_enter;
    my ( $pkg, @args ) = @_;
    my %opts = validate @args, $pkg->_fetch_backend_validate_spec();

    my $apiset            = $opts{apiset};
    my $requested_fields  = $opts{requested_fields};
    my $filter            = $opts{filter};
    my $command_interface = $opts{command_interface};

    my $nfs_args = $pkg->_hash_copy( source => $filter, );

    my ( $response, $caught_exception, $parsed_output );
    try {

        # caling the gui api to get nfs status
        $response      = $apiset->get_nfs_info(%$nfs_args);
        $parsed_output = $response->get_parsed_output();
    } ## end try
    catch NACL::APISet::Exceptions::CommandFailedException with {

        # A caught exception indicates that the nfs is either not licensed
        # or not configured. We catch the exception and return immediately.
        # The 'fetch' frontend decides whether to throw a NoElementsFound
        # exception based on the value of 'allow_empty'
        $Log->debug(
            'CommandFailedException caught. NFS is not licensed/configured');
        $caught_exception = 1;
    };
    if ($caught_exception) {
        $Log->exit() if $may_exit;
        return;
    }

    my %final_attributes = (%$parsed_output);
    my $obj = $pkg->new( command_interface => $command_interface );
    $obj->_set_fields( row => \%final_attributes );
    $Log->exit() if $may_exit;

    return $obj;
} ## end sub _fetch_7mode_gui

1;