# $Id$
#
# Copyright (c) 2001-2010 NetApp, Inc., All Rights Reserved
#   Any use, modification, or distribution is prohibited
#   without prior written consent from NetApp, Inc.
#

## @summary VolumeEfficiency ComponentState Module
## @author vikas.p@netapp.com
## @status shared
## @pod here

=head1 NAME

NACL::CS::SysManager::VolumeEfficiency

=head1 DESCRIPTION

C<NACL::CS::SysManager::VolumeEfficiency> is a derived class of
L<NACL::CS::ComponentState::SysManager|lib-NACL-CS-ComponentState-SysManager-pm>. It represents the
state of an ONTAP VolumeEfficiency.  A related class is
L<NACL::C::SysManager::VolumeEfficiency|lib-NACL-C-SysManager-VolumeEfficiency-pm>, 
which represents access to an ONTAP VolumeEfficiency.

=head1 ATTRIBUTES

The individual pieces of data that are part of the  state of the VolumeEfficiency
element are the attributes of the VolumeEfficiency ComponentState.

=over

=item C<< volume >>

The name of the volume element whose state is being represented.

=item C<< vserver >>

=item C<< "enable" >>

=item C<< "mode" >>

=item C<< "status" >>

=item C<< "type" >>

=item C<< "spacesaved" >>

=item C<< "savedpercentage" >>

=item C<< "starttime" >>

=item C<< "endtime" >>

=back

=cut

package NACL::CS::SysManager::VolumeEfficiency;

use strict;
use warnings;
use Params::Validate qw(validate);
use NATE::Log qw(log_global);
my $Log = log_global();
my $may_enter = $Log->may_enter();
my $may_exit  = $Log->may_exit();
use Data::Dumper;

use base 'NACL::CS::ComponentState::SysManager';

use NACL::C::SysManager::VolumeEfficiency;
use NACL::Exceptions::NoElementsFound qw(:try);

# Import Exception class
use NACL::APISet::Exceptions::ResponseException qw(:try);
use NACL::APISet::Exceptions::CommandFailedException;

use Class::MethodMaker [
    scalar => 'vserver',
    scalar => 'volume',
    scalar => 'enable',
    scalar => 'mode',
    scalar => 'status',
    scalar => 'type',
    scalar => 'spacesaved',
    scalar => 'savedpercentage',
    scalar => 'starttime',
    scalar => 'endtime',
    scalar => 'compression',
];

=head1 METHODS

=head2 fetch

    my $VolumeEfficiency_state   = 
		NACL::CS::SysManager::VolumeEfficiency->fetch(command_interface => $ci, ...);
	my @VolumeEfficiency_states  = 
		NACL::CS::SysManager::VolumeEfficiency->fetch(command_interface => $ci, ...);

see L<NACL::CS::ComponentState|lib-NACL-CS-ComponentState-pm>.

Uses a CMode GUI or a 7Mode GUI APISet.
(Works only when volume and vserver parameters are passed under filter option).

=cut

sub fetch {
    $Log->enter() if $may_enter;
    my ( $pkg, @args ) = @_;

    my @state_objs = $pkg->SUPER::fetch(
        @args,
        choices => [
            {   method => "_fetch_cmode_gui",
                set    => "SysManager_CMode",
            },
            {   method => '_fetch_7mode_gui',
                set    => 'SysManager_7Mode',
            },
        ],
        exception_text => 'No matching volume efficiency found',
    );

    $Log->exit() if $may_exit;
    return wantarray ? @state_objs : $state_objs[0];
} ## end sub fetch

####################### GUI CMode Fetch ###############################
sub _fetch_cmode_gui {
    $Log->enter() if $may_enter;
    my ( $pkg, @args ) = @_;
    my %opts = validate @args, $pkg->_fetch_backend_validate_spec();

    my $apiset            = $opts{apiset};
    my $requested_fields  = $opts{requested_fields};
    my $filter            = $opts{filter};
    my $command_interface = $opts{command_interface};

    my $vol_args = $pkg->_hash_copy(
        source => $filter,
        map    => {
            "volume"  => "-volname",
            "vserver" => "-vservername",
        }
    );

    $pkg->_check_for_required_filter_fields(
        filter          => $filter,
        required_fields => [qw(volume vserver)],
    );

    my ( $response, $caught_exception, $parsed_output );
    try {

        # caling the gui api to get volume efficiency status
        $response      = $apiset->vol_storageeff_info(%$vol_args);
        $parsed_output = $response->get_parsed_output();
    } ## end try
    catch NACL::APISet::Exceptions::CommandFailedException with {

    # A caught exception indicates that the volume efficiency being looked for
    # does not exist. We catch the exception and return immediately.
    # The 'fetch' frontend decides whether to throw a NoElementsFound
    # exception based on the value of 'allow_empty'
        $Log->debug( 'CommandFailedException caught. Requested volume does '
                . 'not exist' );
        $caught_exception = 1;
    };
    if ($caught_exception) {
        $Log->exit() if $may_exit;
        return;
    }

    my %state_base_field_settings;

    $state_base_field_settings{'volume'}  = $vol_args->{'-volname'};
    $state_base_field_settings{'vserver'} = $vol_args->{'-vservername'};
    $state_base_field_settings{'state'}   = $parsed_output->{'status'};

    my %final_attributes = ( %state_base_field_settings, %$parsed_output );

    my $obj = $pkg->new( command_interface => $command_interface );
    $obj->_set_fields( row => \%final_attributes );
    $Log->exit() if $may_exit;

    return $obj;
} ## end sub _fetch_cmode_gui

####################### GUI 7Mode Fetch ###############################
sub _fetch_7mode_gui {
    $Log->enter() if $may_enter;
    my ( $pkg, @args ) = @_;
    my %opts = validate @args, $pkg->_fetch_backend_validate_spec();

    my $apiset            = $opts{apiset};
    my $requested_fields  = $opts{requested_fields};
    my $filter            = $opts{filter};
    my $command_interface = $opts{command_interface};

    my $vol_args = $pkg->_hash_copy(
        source => $filter,
        map    => { "volume" => "-volname", }
    );

    $pkg->_check_for_required_filter_fields(
        filter          => $filter,
        required_fields => [qw(volume)],
    );

    my ( $response, $caught_exception, $parsed_output );
    try {

        # caling the gui api to get volume efficieny status
        $response      = $apiset->vol_storageeff_info(%$vol_args);
        $parsed_output = $response->get_parsed_output();
    } ## end try
    catch NACL::APISet::Exceptions::CommandFailedException with {

    # A caught exception indicates that the volume efficiency being looked for
    # does not exist. We catch the exception and return immediately.
    # The 'fetch' frontend decides whether to throw a NoElementsFound
    # exception based on the value of 'allow_empty'
        $Log->debug( 'CommandFailedException caught. Requested volume does '
                . 'not exist' );
        $caught_exception = 1;
    };
    if ($caught_exception) {
        $Log->exit() if $may_exit;
        return;
    }

    my %state_base_field_settings;

    $state_base_field_settings{'volume'} = $vol_args->{'-volname'};
    $state_base_field_settings{'state'}  = $parsed_output->{'status'};

    my %final_attributes = ( %state_base_field_settings, %$parsed_output );

    my $obj = $pkg->new( command_interface => $command_interface );
    $obj->_set_fields( row => \%final_attributes );
    $Log->exit() if $may_exit;

    return $obj;
} ## end sub _fetch_7mode_gui

1;